Commit 07d8739

@@ -0,0 +1,539 @@
+# Port from home-manager's programs.floorp
+# See https://github.com/nix-community/home-manager/tree/c53d643b3737e2fcd04e6cb3b3580ef50b2087a0/modules/programs/firefox
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib) concatStrings mapAttrsToList mkIf mkMerge mkOption optionalAttrs;
+  inherit (lib.types) attrsOf bool ints listOf nullOr package path str submodule;
+
+  modulePath = ["programs" "floorp"];
+  cfg = config.programs.floorp;
+
+  appName = "Floorp";
+  configPath = ".floorp";
+  extensionPath = "extensions/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}";
+
+  jsonFormat = pkgs.formats.json {};
+
+  userPrefValue = pref:
+    builtins.toJSON (
+      if lib.isBool pref || lib.isInt pref || lib.isString pref || lib.isPath pref
+      then pref
+      else builtins.toJSON pref
+    );
+
+  extensionSettingsNeedForce = extensionSettings:
+    builtins.any (ext: ext.settings != {}) (builtins.attrValues extensionSettings);
+
+  extensionSettingsMissingForce = extensionSettings:
+    builtins.any (ext: ext.settings != {} && !ext.force) (builtins.attrValues extensionSettings);
+
+  mkUserJs = prePrefs: prefs: extraPrefs: extensions: let
+    prefs' =
+      optionalAttrs (extensionSettingsNeedForce extensions) {
+        "extensions.webextensions.ExtensionStorageIDB.enabled" = false;
+      }
+      // prefs;
+  in ''
+    // Generated by Hjem.
+
+    ${prePrefs}
+
+    ${concatStrings (
+      mapAttrsToList (name: value: ''
+        user_pref("${name}", ${userPrefValue value});
+      '')
+      prefs'
+    )}
+
+    ${extraPrefs}
+  '';
+
+  profilesIni = lib.generators.toINI {} (
+    lib.flip lib.mapAttrs' cfg.profiles (
+      _: profile:
+        lib.nameValuePair "Profile${toString profile.id}" {
+          Name = profile.name;
+          Path = profile.path;
+          IsRelative = 1;
+          Default =
+            if profile.isDefault
+            then 1
+            else 0;
+        }
+    )
+    // {
+      General = {
+        StartWithLastProfile = 1;
+      };
+    }
+  );
+
+  effectivePolicies =
+    cfg.policies
+    // lib.optionalAttrs (cfg.languagePacks != []) {
+      ExtensionSettings =
+        (cfg.policies.ExtensionSettings or {})
+        // lib.listToAttrs (map (lang:
+          lib.nameValuePair "langpack-${lang}@firefox.mozilla.org" {
+            installation_mode = "normal_installed";
+            install_url = "https://releases.mozilla.org/pub/firefox/releases/${cfg.release}/linux-x86_64/xpi/${lang}.xpi";
+          })
+        cfg.languagePacks);
+    };
+
+  mkSearchModule = {
+    pkgs,
+    modulePath,
+    profilePath,
+    package,
+  }: {
+    config,
+    lib,
+    ...
+  }: let
+    internalFieldNames =
+      lib.genAttrs
+      [
+        "name"
+        "isAppProvided"
+        "loadPath"
+        "updateInterval"
+        "updateURL"
+        "iconMapObj"
+        "metaData"
+        "orderHint"
+        "definedAliases"
+        "urls"
+      ] (name: "_${name}")
+      // {
+        searchForm = "__searchForm";
+      };
+
+    iconUrl = icon:
+      if lib.isPath icon || lib.hasPrefix "/" icon
+      then "file://${icon}"
+      else icon;
+
+    processCustomEngineInput = input:
+      {
+        name = input.id;
+      }
+      // (removeAttrs input ["icon"])
+      // optionalAttrs (input ? icon || input ? iconMapObj) {
+        iconMapObj = lib.mapAttrs (_name: iconUrl) (
+          (optionalAttrs (input ? icon) {
+            # Convenience to specify single icon instead of a map
+            "16" = input.icon;
+          })
+          // (input.iconMapObj or {})
+        );
+      }
+      // {
+        # Required for custom engine configurations; loadPaths are
+        # unique identifiers generally formatted as [source]/path/to/engine
+        loadPath = "[hjem]/${lib.showAttrPath (modulePath ++ ["engines" input.id])}";
+      };
+
+    processEngineInput = id: input: let
+      requiredInput = {
+        inherit id;
+        isAppProvided = input.isAppProvided or (removeAttrs input ["metaData"] == {});
+        metaData = input.metaData or {};
+      };
+    in
+      if requiredInput.isAppProvided
+      then requiredInput
+      else processCustomEngineInput (input // requiredInput);
+
+    buildEngineConfig = name: input:
+      lib.mapAttrs' (name: value: {
+        name = internalFieldNames.${name} or name;
+        inherit value;
+      }) (processEngineInput name input);
+
+    sortEngineConfigs = configs: let
+      buildEngineConfigWithOrder = order: id: let
+        config =
+          configs.${
+            id
+          } or {
+            inherit id;
+            _isAppProvided = true;
+            _metaData = {};
+          };
+      in
+        config // {_metaData = config._metaData // {inherit order;};};
+
+      engineConfigsWithoutOrder = lib.attrValues (removeAttrs configs config.order);
+
+      sortedEngineConfigs =
+        (lib.imap buildEngineConfigWithOrder config.order) ++ engineConfigsWithoutOrder;
+    in
+      sortedEngineConfigs;
+
+    engineInput =
+      config.engines
+      // {
+        # Infer defaults as app-provided engines if they're not in engines.
+        ${config.default} = config.engines.${config.default} or {};
+      }
+      // {
+        ${config.privateDefault} = config.engines.${config.privateDefault} or {};
+      };
+
+    settings = {
+      version = 12;
+      engines = sortEngineConfigs (lib.mapAttrs buildEngineConfig engineInput);
+
+      metaData =
+        optionalAttrs (config.default != null) {
+          defaultEngineId = config.default;
+          defaultEngineIdHash = "@hash@";
+        }
+        // optionalAttrs (config.privateDefault != null) {
+          privateDefaultEngineId = config.privateDefault;
+          privateDefaultEngineIdHash = "@privateHash@";
+        }
+        // {
+          useSavedOrder = config.order != [];
+        };
+    };
+
+    disclaimer =
+      "By modifying this file, I agree that I am doing so "
+      + "only within @appName@ itself, using official, user-driven search "
+      + "engine selection processes, and in a way which does not circumvent "
+      + "user consent. I acknowledge that any attempt to change this file "
+      + "from outside of @appName@ is a malicious act, and will be responded "
+      + "to accordingly.";
+
+    salt =
+      if config.default != null
+      then profilePath + config.default + disclaimer
+      else null;
+
+    privateSalt =
+      if config.privateDefault != null
+      then profilePath + config.privateDefault + disclaimer
+      else null;
+
+    appNameVariable =
+      if package == null
+      then "appName=${lib.escapeShellArg appName}"
+      else ''
+        applicationIni="$(find ${lib.escapeShellArg package} -maxdepth 3 -path ${lib.escapeShellArg package}'/lib/*/application.ini' -print -quit)"
+        if test -n "$applicationIni"; then
+          appName="$(sed -n 's/^Name=\(.*\)$/\1/p' "$applicationIni" | head -n1)"
+        else
+          appName=${lib.escapeShellArg appName}
+        fi
+      '';
+
+    file =
+      pkgs.runCommand "search.json.mozlz4" {
+        nativeBuildInputs = with pkgs; [
+          mozlz4a
+          openssl
+        ];
+        json = builtins.toJSON settings;
+        inherit salt privateSalt;
+      } ''
+        ${appNameVariable}
+
+        salt=''${salt//@appName@/"$appName"}
+        privateSalt=''${privateSalt//@appName@/"$appName"}
+
+        if [[ -n $salt ]]; then
+          export hash=$(echo -n "$salt" | openssl dgst -sha256 -binary | base64)
+          export privateHash=$(echo -n "$privateSalt" | openssl dgst -sha256 -binary | base64)
+          mozlz4a <(substituteStream json search.json.in --subst-var hash --subst-var privateHash) "$out"
+        else
+          mozlz4a <(echo "$json") "$out"
+        fi
+      '';
+  in {
+    options = {
+      enable = mkOption {
+        type = bool;
+        default = config.default != null || config.privateDefault != null || config.order != [] || config.engines != {};
+        internal = true;
+      };
+
+      force = mkOption {
+        type = bool;
+        default = false;
+        description = ''
+          Whether to force replace the existing search configuration.
+        '';
+      };
+
+      default = mkOption {
+        type = nullOr str;
+        default = null;
+      };
+
+      privateDefault = mkOption {
+        type = nullOr str;
+        default = null;
+      };
+
+      order = mkOption {
+        type = listOf str;
+        default = [];
+      };
+
+      engines = mkOption {
+        type = attrsOf (attrsOf jsonFormat.type);
+        default = {};
+      };
+
+      file = mkOption {
+        type = path;
+        default = file;
+        internal = true;
+        readOnly = true;
+      };
+    };
+  };
+in {
+  options = lib.setAttrByPath modulePath {
+    enable = mkOption {
+      type = bool;
+      default = false;
+      example = true;
+    };
+
+    package = mkOption {
+      type = nullOr package;
+      default = pkgs.floorp-bin;
+      defaultText = lib.literalExpression "pkgs.floorp-bin";
+    };
+
+    finalPackage = mkOption {
+      type = nullOr package;
+      readOnly = true;
+    };
+
+    release = mkOption {
+      internal = true;
+      type = str;
+    };
+
+    policies = mkOption {
+      type = attrsOf jsonFormat.type;
+      default = {};
+    };
+
+    languagePacks = mkOption {
+      type = listOf str;
+      default = [];
+    };
+
+    profiles = mkOption {
+      type = attrsOf (submodule (
+        {
+          name,
+          config,
+          ...
+        }: {
+          options = {
+            name = mkOption {
+              type = str;
+              default = name;
+            };
+
+            id = mkOption {
+              type = ints.unsigned;
+              default = 0;
+            };
+
+            isDefault = mkOption {
+              type = bool;
+              default = config.id == 0;
+            };
+
+            path = mkOption {
+              type = str;
+              default = name;
+            };
+
+            preConfig = mkOption {
+              type = str;
+              default = "";
+            };
+
+            settings = mkOption {
+              type = attrsOf jsonFormat.type;
+              default = {};
+            };
+
+            extraConfig = mkOption {
+              type = str;
+              default = "";
+            };
+
+            search = mkOption {
+              type = submodule (mkSearchModule {
+                inherit pkgs;
+                modulePath = modulePath ++ ["profiles" name "search"];
+                profilePath = config.path;
+                package = cfg.finalPackage;
+              });
+              default = {};
+            };
+
+            extensions = mkOption {
+              type = submodule {
+                options = {
+                  packages = mkOption {
+                    type = listOf package;
+                    default = [];
+                  };
+
+                  force = mkOption {
+                    type = bool;
+                    default = false;
+                  };
+
+                  settings = mkOption {
+                    type = attrsOf (submodule {
+                      options = {
+                        settings = mkOption {
+                          type = attrsOf jsonFormat.type;
+                          default = {};
+                        };
+
+                        force = mkOption {
+                          type = bool;
+                          default = false;
+                        };
+                      };
+                    });
+                    default = {};
+                  };
+                };
+              };
+              default = {};
+            };
+          };
+        }
+      ));
+      default = {};
+    };
+  };
+
+  config = mkIf cfg.enable (
+    {
+      assertions =
+        mapAttrsToList (name: profile: {
+          assertion = !(extensionSettingsMissingForce profile.extensions.settings) || profile.extensions.force;
+          message = ''
+            programs.floorp: profile '${name}': using 'profiles.${name}.extensions.settings' will
+            override all previous extension settings. Enable either
+            'profiles.${name}.extensions.force' or the corresponding
+            'profiles.${name}.extensions.settings.<extensionId>.force' to acknowledge this.
+          '';
+        })
+        cfg.profiles
+        ++ [
+          {
+            assertion = cfg.languagePacks == [] || cfg.package != null;
+            message = "programs.floorp: languagePacks requires package to be set to a non-null value.";
+          }
+        ];
+
+      packages = lib.optional (cfg.finalPackage != null) cfg.finalPackage;
+
+      files = mkMerge ([
+          (mkIf (cfg.profiles != {}) {
+            "${configPath}/profiles.ini".text = profilesIni;
+          })
+        ]
+        ++ mapAttrsToList (
+          _: profile: let
+            extensionPackages =
+              builtins.filter (pkg: pkg ? addonId) profile.extensions.packages;
+            skippedExtensions =
+              builtins.filter (pkg: !(pkg ? addonId)) profile.extensions.packages;
+          in
+            mkMerge [
+              {
+                "${configPath}/${profile.path}".type = "directory";
+              }
+
+              (mkIf (
+                  profile.preConfig
+                  != ""
+                  || profile.settings != {}
+                  || profile.extraConfig != ""
+                  || extensionSettingsNeedForce profile.extensions.settings
+                ) {
+                  "${configPath}/${profile.path}/user.js".text = mkUserJs profile.preConfig profile.settings profile.extraConfig profile.extensions.settings;
+                })
+
+              (mkIf profile.search.enable {
+                "${configPath}/${profile.path}/search.json.mozlz4" = {
+                  source = profile.search.file;
+                  clobber = profile.search.force;
+                };
+              })
+
+              (mkIf (profile.extensions.packages != []) (
+                lib.warnIf (skippedExtensions != [])
+                "programs.floorp: extensions without `addonId` cannot be linked into the profile: ${
+                  builtins.concatStringsSep ", " (map (pkg: pkg.name) skippedExtensions)
+                }"
+                ({
+                    "${configPath}/${profile.path}/extensions" = {
+                      type = "directory";
+                      clobber = true;
+                    };
+                  }
+                  // lib.listToAttrs (map (pkg: {
+                      name = "${configPath}/${profile.path}/extensions/${pkg.addonId}.xpi";
+                      value = {
+                        source = "${pkg}/share/mozilla/${extensionPath}/${pkg.addonId}.xpi";
+                        clobber = true;
+                      };
+                    })
+                    extensionPackages))
+              ))
+
+              (mkMerge (mapAttrsToList
+                (
+                  extId: ext:
+                    mkIf (ext.settings != {}) {
+                      "${configPath}/${profile.path}/browser-extension-data/${extId}/storage.js" = {
+                        text = lib.generators.toJSON {} ext.settings;
+                        clobber = ext.force || profile.extensions.force;
+                      };
+                    }
+                )
+                profile.extensions.settings))
+            ]
+        )
+        cfg.profiles);
+    }
+    // lib.setAttrByPath modulePath {
+      finalPackage =
+        if cfg.package == null
+        then null
+        else if cfg.package.override.__functionArgs ? cfg
+        then
+          cfg.package.override (old: {
+            cfg = old.cfg or {};
+            extraPolicies = (old.extraPolicies or {}) // effectivePolicies;
+          })
+        else
+          lib.warn
+          "programs.floorp: package does not support overriding; policies and language packs will not be applied."
+          cfg.package;
+
+      release = lib.mkOptionDefault (builtins.head (lib.splitString "-" cfg.package.version));
+    }
+  );
+}

@@ -0,0 +1,219 @@
+{
+  den,
+  lib,
+  ...
+}: {
+  den.aspects.desktop.app.browser.floorp = {
+    includes = [den.aspects.desktop.app.browser];
+
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.directory}/.floorp"
+      ];
+    };
+
+    hjem = {pkgs, ...}: {
+      imports = [./_hjem-module.nix];
+
+      programs.floorp = {
+        enable = true;
+
+        policies = {
+          DisableAppUpdate = true;
+          DisablePocket = true;
+          DisableSetDesktopBackground = true;
+          DisableTelemetry = true;
+          DontCheckDefaultBrowser = true;
+          ExtensionUpdate = false;
+          NoDefaultBookmarks = true;
+          OfferToSaveLogins = false;
+          PasswordManagerEnabled = false;
+        };
+
+        profiles.default = {
+          id = 0;
+          isDefault = true;
+
+          search = {
+            force = true;
+            default = "kagi";
+            privateDefault = "kagi";
+            order = [
+              "kagi"
+              "bing"
+              "google"
+              "ddg"
+            ];
+            engines = {
+              kagi = {
+                name = "Kagi";
+                description = "A privacy-focused, user-centric search engine.";
+                urls = [
+                  {template = "https://kagi.com/search?q={searchTerms}";}
+                  {
+                    type = "application/x-suggestions+json";
+                    template = "https://kagisuggest.com/api/autosuggest?q={searchTerms}";
+                  }
+                ];
+                iconMapObj = {
+                  "16" = "https://kagi.com/favicon-16x16.png";
+                  "32" = "https://kagi.com/favicon-32x32.png";
+                };
+                definedAliases = ["@kagi"];
+              };
+
+              baidu.metaData.hidden = true;
+              startpage.metaData.hidden = true;
+              "you.com".metaData.hidden = true;
+            };
+          };
+
+          extensions.force = true;
+          extensions.packages = with pkgs.nur.repos.rycee.firefox-addons; [
+            ublock-origin
+            bitwarden
+            tampermonkey
+            kiss-translator
+          ];
+
+          settings = {
+            # == General ==
+            "browser.startup.page" = 3; # Open prev session pages
+            "browser.tabs.unloadOnLowMemory" = true;
+            "widget.use-xdg-desktop-portal.file-picker" = 1;
+            # No first run
+            "app.normandy.first_run" = false;
+            "doh-rollout.doneFirstRun" = true;
+            "toolkit.telemetry.reportingpolicy.firstRun" = false;
+            "trailhead.firstrun.didSeeAboutWelcome" = true;
+            "browser.toolbarbuttons.introduced.sidebar-button" = true;
+            "sidebar.old-sidebar.has-used" = true;
+            "sidebar.new-sidebar.has-used" = true;
+            "floorp.browser.welcome.page.shown" = true;
+            # Language
+            "general.useragent.locale" = "zh-CN";
+            "intl.locale.requested" = "zh-CN,en-US";
+            "browser.translations.mostRecentTargetLanguages" = "zh-Hans";
+            # No ads
+            "browser.urlbar.suggest.topsites" = false;
+            "browser.urlbar.suggest.trending" = false;
+            "browser.newtabpage.pinned" = [];
+            "browser.newtabpage.activity-stream.showSponsored" = false;
+            "browser.newtabpage.activity-stream.showSponsoredTopSites" = false;
+            "browser.ai.control.sidebarChatbot" = "blocked";
+            # == Telemetry ==
+            "toolkit.telemetry.unified" = false;
+            "toolkit.telemetry.enabled" = false;
+            "toolkit.telemetry.server" = "data:,";
+            "toolkit.telemetry.archive.enabled" = false;
+            "toolkit.telemetry.newProfilePing.enabled" = false;
+            "toolkit.telemetry.shutdownPingSender.enabled" = false;
+            "toolkit.telemetry.updatePing.enabled" = false;
+            "toolkit.telemetry.bhrPing.enabled" = false;
+            "toolkit.telemetry.firstShutdownPing.enabled" = false;
+            "toolkit.telemetry.shutdownPingSender.enabledFirstsession" = false;
+            "browser.ping-centre.telemetry" = false;
+            "browser.newtabpage.activity-stream.feeds.telemetry" = false;
+            "browser.newtabpage.activity-stream.telemetry" = false;
+            # == Appearance ==
+            "browser.newtabpage.activity-stream.feeds.topsites" = false;
+            "browser.newtabpage.activity-stream.default.sites" = "";
+            "browser.toolbars.bookmarks.visibility" = "always";
+            "sidebar.verticalTabs" = true;
+            "sidebar.main.tools" = "syncedtabs";
+            "sidebar.visibility" = "expand-on-hover";
+            # Floorp's new tab page
+            "floorp.newtab.configs" = {
+              "backround"."type" = "none";
+              "components" = {
+                "topSites" = false;
+                "clock" = false;
+                "searchBar" = true;
+                "firefoxLayout" = true;
+              };
+              "searchBar" = {"searchEngine" = "default";};
+              "topSites" = {
+                "pinned" = [];
+                "blocked" = [];
+              };
+            };
+            # panelSideBar
+            "floorp.panelSidebar.enabled" = true;
+            "floorp.panelSidebar.config" = {
+              "autoUnload" = false;
+              "position_start" = true;
+              "globalWidth" = 400;
+              "displayed" = true;
+              "webExtensionRunningEnabled" = false;
+            };
+            "floorp.panelSidebar.data"."data" =
+              (lib.map (x: {
+                "id" = "default-panel-${x}";
+                "url" = "floorp//${x}";
+                "width" = 0;
+                "type" = "static";
+              }) ["bookmarks" "history" "downloads"])
+              ++ (lib.map (url: let
+                  id = lib.pipe url [
+                    (x: lib.removePrefix "http://" x)
+                    (x: lib.removePrefix "https://" x)
+                    (x: lib.splitString "?" x)
+                    (x: lib.elemAt x 0)
+                    (x: lib.replaceStrings ["/" "."] ["-" "-"] x)
+                    (x: lib.removeSuffix "-" x)
+                    (x: "panel-${x}")
+                  ];
+                in {
+                  inherit id url;
+                  "width" = 0;
+                  "userContextId" = 0;
+                  "zoomLevel" = null;
+                  "type" = "web";
+                }) [
+                  "https://translate.kagi.com"
+                  "https://squoosh.app"
+                ]);
+            # Workspace
+            "floorp.workspaces.enabled" = true;
+            "floorp.workspaces.v4.config" = {
+              "manageOnBms" = true;
+              "showWorkspaceNameOnToolbar" = true;
+            };
+            # Top toolbar
+            "browser.uiCustomization.state" = {
+              "placements" = {
+                "widget-overflow-fixed-list" = [];
+                "unified-extensions-area" = [
+                  "firefox_tampermonkey_net-browser-action" # Tampermonkey
+                  "ublock0_raymondhill_net-browser-action" # uBlock Origin
+                ];
+                "nav-bar" = [
+                  "sidebar-button"
+                  "back-button"
+                  "forward-button"
+                  "stop-reload-button"
+                  "vertical-spacer"
+                  "urlbar-container"
+                  "_446900e4-71c2-419f-a6a7-df9c091e268b_-browser-action" # Bitwarden
+                  "unified-extensions-button"
+                  "fxa-toolbar-menu-button"
+                ];
+                "toolbar-menubar" = ["menubar-items"];
+                "TabsToolbar" = [];
+                "vertical-tabs" = ["tabbrowser-tabs"];
+                "PersonalToolbar" = ["personal-bookmarks"];
+                "nora-statusbar" = [
+                  "screenshot-button"
+                  "fullscreen-button"
+                  "status-text"
+                ];
+              };
+              "seen" = ["developer-button"];
+              "dirtyAreaCache" = [];
+            };
+          };
+        };
+      };
+    };
+  };
+}

@@ -0,0 +1,34 @@
+{
+  den,
+  lib,
+  ...
+}: {
+  den.aspects.desktop.app.browser.chromium = {
+    includes = [den.aspects.desktop.app.browser];
+
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.config.directory}/chromium"
+      ];
+    };
+
+    hjem = {pkgs, ...}: let
+      extensions = [
+        "nngceckbapebfimnlniiiahkandclblb" # Bitwarden
+        "ddkjiahejlhfcafbddmgiahcphecmpfh" # Ublock Origin Lite
+      ];
+    in {
+      packages = [pkgs.chromium];
+
+      xdg.config.files =
+        lib.genAttrs'
+        extensions
+        (id: {
+          name = "chromium/External Extensions/${id}.json";
+          value.text = builtins.toJSON {
+            external_update_url = "https://clients2.google.com/service/update2/crx";
+          };
+        });
+    };
+  };
+}

@@ -0,0 +1,36 @@
+{lib, ...}: {
+  den.aspects.desktop.app.browser = {
+    settings.user = {
+      defaults = lib.mkOption {
+        type = lib.types.listOf lib.types.str;
+        description = "Default browsers' desktop entries";
+        default = [];
+      };
+    };
+    hjem = {user, ...}: let
+      cfg = user.system.settings.desktop.app.browser;
+      desktopEntries = cfg.defaults;
+    in {
+      xdg.mime-apps.default-applications = {
+        "application/json" = desktopEntries;
+        "text/html" = desktopEntries;
+        "text/xml" = desktopEntries;
+        "application/xml" = desktopEntries;
+        "application/xhtml+xml" = desktopEntries;
+        "application/xhtml_xml" = desktopEntries;
+        "application/rdf+xml" = desktopEntries;
+        "application/rss+xml" = desktopEntries;
+        "application/x-extension-htm" = desktopEntries;
+        "application/x-extension-html" = desktopEntries;
+        "application/x-extension-shtml" = desktopEntries;
+        "application/x-extension-xht" = desktopEntries;
+        "application/x-extension-xhtml" = desktopEntries;
+
+        "x-scheme-handler/about" = desktopEntries;
+        "x-scheme-handler/ftp" = desktopEntries;
+        "x-scheme-handler/http" = desktopEntries;
+        "x-scheme-handler/https" = desktopEntries;
+      };
+    };
+  };
+}

@@ -0,0 +1,19 @@
+{lib, ...}: {
+  den.aspects.desktop.app.term = {
+    settings.user = {
+      default = lib.mkOption {
+        type = lib.types.nullOr lib.types.str;
+        description = "Default terminal's binary name";
+        default = null;
+      };
+    };
+
+    provides.to-users = {
+      hjem = {pkgs, ...}: {
+        packages = [pkgs.xdg-terminal-exec];
+
+        xdg.config.files."xdg-terminals.list".text = "";
+      };
+    };
+  };
+}

@@ -0,0 +1,34 @@
+{den, ...}: {
+  den.aspects.desktop.app.term.foot = {
+    includes = [den.aspects.desktop.app.term];
+    hjem = {
+      user,
+      pkgs,
+      lib,
+      ...
+    }: {
+      packages = [pkgs.foot];
+
+      xdg.config.files."foot/foot.ini" = {
+        generator = (pkgs.formats.ini {}).generate "foot-config.ini";
+        value = {
+          main = {
+            pad = "10x10";
+          };
+        };
+      };
+
+      xdg.config.files."xdg-terminals.list".text =
+        lib.mkOrder
+        (1000 # Default order
+          + (
+            if (user.system.settings.desktop.app.term.default == "foot")
+            then -500 # lib.mkBefore
+            else 500 # lib.mkAfter
+          ))
+        ''
+          foot.desktop
+        '';
+    };
+  };
+}

@@ -0,0 +1,17 @@
+{
+  den.aspects.desktop.app.imv = {
+    hjem = {pkgs, ...}: {
+      packages = [pkgs.imv];
+
+      xdg.mime-apps.default-applications = {
+        "image/jpeg" = ["imv.desktop"];
+        "image/avif" = ["imv.desktop"];
+        "image/png" = ["imv.desktop"];
+        "image/gif" = ["imv.desktop"];
+        "image/webp" = ["imv.desktop"];
+        "image/svg+xml" = ["imv.desktop"];
+        "image/bmp" = ["imv.desktop"];
+      };
+    };
+  };
+}

@@ -0,0 +1,39 @@
+{
+  den.aspects.desktop.app.kdeconnect = {
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.config.directory}/kdeconnect"
+      ];
+    };
+
+    nixos = {
+      networking.firewall = {
+        allowedTCPPortRanges = [
+          {
+            from = 1714;
+            to = 1764;
+          }
+        ];
+        allowedUDPPortRanges = [
+          {
+            from = 1714;
+            to = 1764;
+          }
+        ];
+      };
+    };
+
+    hjem = {pkgs, ...}: {
+      packages = [pkgs.kdePackages.kdeconnect-kde];
+
+      systemd.services.kdeconnect = {
+        description = "Adds communication between your desktop and your smartphone";
+        partOf = ["graphical-session.target"];
+        after = ["graphical-session.target"];
+        wantedBy = ["graphical-session.target"];
+        script = "${pkgs.kdePackages.kdeconnect-kde}/bin/kdeconnectd";
+        serviceConfig.Restart = "on-abort";
+      };
+    };
+  };
+}

@@ -0,0 +1,16 @@
+{
+  den.aspects.desktop.app.kdenlive = {
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.data.directory}/kdenlive"
+      ];
+      files = [
+        "${config.xdg.config.directory}/kdenliverc"
+      ];
+    };
+
+    hjem = {pkgs, ...}: {
+      packages = [pkgs.kdePackages.kdenlive];
+    };
+  };
+}

@@ -0,0 +1,17 @@
+{
+  den.aspects.desktop.app.libreoffice = {
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.config.directory}/libreoffice"
+      ];
+    };
+
+    nixos = {pkgs, ...}: {
+      fonts.packages = [pkgs.nur.repos.rewine.ttf-ms-win10];
+    };
+
+    hjem = {pkgs, ...}: {
+      packages = [pkgs.libreoffice];
+    };
+  };
+}

@@ -0,0 +1,148 @@
+{
+  den.aspects.desktop.app.mpv = {
+    cacheHome = {config, ...}: {
+      directories = [
+        "${config.xdg.state.directory}/mpv"
+      ];
+    };
+
+    hjem = {
+      pkgs,
+      lib,
+      ...
+    }: let
+      # Port of home-manager's programs.mpv
+      # See https://github.com/nix-community/home-manager/blob/c53d643b3737e2fcd04e6cb3b3580ef50b2087a0/modules/programs/mpv.nix
+      mpvConfGenerator = {
+        defaultProfiles ? [],
+        config ? {},
+        profiles ? {},
+        includes ? [],
+      }: let
+        renderOption = option:
+          if lib.isBool option
+          then
+            (
+              if option
+              then "yes"
+              else "no"
+            )
+          else toString option;
+
+        renderOptionValue = value: let
+          rendered = renderOption value;
+        in "%${toString (builtins.stringLength rendered)}%${rendered}";
+
+        mkKeyValue = lib.generators.mkKeyValueDefault {
+          mkValueString = renderOptionValue;
+        } "=";
+
+        renderOptions = lib.generators.toKeyValue {
+          inherit mkKeyValue;
+          listsAsDuplicateKeys = true;
+        };
+
+        renderProfiles = lib.generators.toINI {
+          inherit mkKeyValue;
+          listsAsDuplicateKeys = true;
+        };
+
+        renderDefaultProfiles = profiles: renderOptions {profile = lib.concatStringsSep "," profiles;};
+      in
+        lib.concatStringsSep "\n" (lib.filter (s: s != "") [
+          (lib.optionalString (defaultProfiles != []) (renderDefaultProfiles defaultProfiles))
+          (lib.optionalString (config != {}) (renderOptions config))
+          (lib.optionalString (profiles != {}) (renderProfiles profiles))
+          (lib.concatMapStringsSep "\n" (include: "include=${include}") includes)
+        ]);
+
+      mpvScriptOptsGenerator = value:
+        lib.generators.toKeyValue {
+          mkKeyValue = lib.generators.mkKeyValueDefault {
+            mkValueString = option:
+              if lib.isBool option
+              then
+                (
+                  if option
+                  then "yes"
+                  else "no"
+                )
+              else toString option;
+          } "=";
+          listsAsDuplicateKeys = true;
+        }
+        value;
+    in {
+      packages = [
+        (pkgs.mpv.override {
+          scripts = with pkgs.mpvScripts; [
+            mpris
+            uosc
+            thumbfast
+            autoload
+            reload
+            mpv-playlistmanager
+          ];
+        })
+      ];
+
+      xdg.config.files = {
+        "mpv/mpv.conf" = {
+          generator = mpvConfGenerator;
+          value = {
+            defaultProfiles = ["gpu-hq"];
+            config = {
+              vo = "gpu-next";
+              hwdec = "auto-copy";
+              scale = "ewa_lanczossharp";
+              # --- 动态范围与色彩管理 --- #
+              target-colorspace-hint = "auto";
+              tone-mapping = "hable";
+              dither = "fruit";
+              dither-depth = "auto";
+              # --- 音频质量配置 --- #
+              ao = "pipewire";
+              audio-resample-filter-size = 64;
+              audio-resample-phase-shift = 10;
+              # --- 字幕配置 --- #
+              sub-auto = "fuzzy";
+              sub-bold = "yes";
+              sub-outline-size = 2.25;
+              sub-outline-color = "#111111";
+              sub-color = "#FEFEFE";
+              sub-font-size = "36";
+              sub-use-margins = "yes";
+              sub-ass-override = "force";
+              # --- 用户体验 --- #
+              save-position-on-quit = true;
+              keep-open = "yes";
+              osd-bar = "no"; # use uosc
+              # 音量控制
+              volume = 80;
+              volume-max = 120;
+              # OSD 显示
+              osd-duration = 2500;
+              osd-font-size = 32;
+              # 截图设置
+              screenshot-format = "png";
+              screenshot-dir = "$XDG_PICTURES_DIR/mpv";
+              screenshot-template = "%F-%P";
+            };
+          };
+        };
+
+        "mpv/script-opts/uosc.conf" = {
+          generator = mpvScriptOptsGenerator;
+          value = {
+            languages = "slang,zh-hans";
+          };
+        };
+      };
+
+      xdg.mime-apps.default-applications = {
+        "audio/*" = ["mpv.desktop"];
+        "video/*" = ["mpv.desktop"];
+      };
+    };
+  };
+}

@@ -0,0 +1,34 @@
+{
+  den.aspects.desktop.app.obs-studio = {
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.config.directory}/obs-studio"
+      ];
+    };
+
+    nixos = {config, ...}: {
+      # From https://github.com/NixOS/nixpkgs/blob/f8cc9d1b80b6c75fec21ecc549f631c3eed5a5e1/nixos/modules/programs/obs-studio.nix
+      boot = {
+        kernelModules = ["v4l2loopback"];
+        extraModulePackages = [config.boot.kernelPackages.v4l2loopback];
+
+        extraModprobeConfig = ''
+          options v4l2loopback devices=1 video_nr=1 card_label="OBS Cam" exclusive_caps=1
+        '';
+      };
+    };
+
+    hjem = {pkgs, ...}: {
+      packages = [
+        (pkgs.wrapOBS {
+          plugins = with pkgs.obs-studio-plugins; [
+            input-overlay
+            obs-pipewire-audio-capture
+            obs-vkcapture
+            obs-backgroundremoval
+          ];
+        })
+      ];
+    };
+  };
+}

@@ -0,0 +1,15 @@
+{
+  den.aspects.desktop.app.picard = {
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.config.directory}/MusicBrainz"
+      ];
+    };
+
+    hjem = {pkgs, ...}: {
+      packages = with pkgs; [
+        picard
+      ];
+    };
+  };
+}

@@ -0,0 +1,22 @@
+diff --git a/ucm2/USB-Audio/Sony/DualSense-PS5.conf b/ucm2/USB-Audio/Sony/DualSense-PS5.conf
+index d6bfb4a..ed7157a 100644
+--- a/ucm2/USB-Audio/Sony/DualSense-PS5.conf
++++ b/ucm2/USB-Audio/Sony/DualSense-PS5.conf
+@@ -5,6 +5,17 @@ Include.dhw.File "/common/directm.conf"
+ # keep this use case first - wine compatibility
+ Macro.0.DirectUseCase { Id="Direct" PlaybackChannels=4 CaptureChannels=2 }
+
++If.setvol.Prepend.SectionUseCase."Direct".Config {
++       SectionVerb {
++               EnableSequence [
++                       cset "name='PCM Playback Volume' 100"
++               ]
++       }
++       SectionDevice."Direct".Value {
++               PlaybackMixerElem "PCM"
++       }
++}
++
+ If.default.Prepend.SectionUseCase."Default" {
+        Comment "Default"
+        File "/USB-Audio/Sony/DualSense-PS5-HiFi.conf"

@@ -0,0 +1,32 @@
+{den, ...}: {
+  den.aspects.desktop.game.includes = [den.aspects.desktop.game.gamepad];
+  den.aspects.desktop.game.gamepad = {
+    nixos = {
+      pkgs,
+      config,
+      ...
+    }: {
+      hardware = {
+        uinput.enable = true;
+        xone.enable = true;
+        xpadneo.enable = true;
+      };
+
+      boot = {
+        extraModulePackages = [
+          config.boot.kernelPackages.xpadneo
+        ];
+        extraModprobeConfig = ''
+          options bluetooth disable_ertm=Y
+        '';
+        kernelModules = [
+          "hid_microsoft"
+        ];
+      };
+
+      services.udev.packages = [
+        pkgs.game-devices-udev-rules
+      ];
+    };
+  };
+}

@@ -0,0 +1,27 @@
+{lib, ...}: {
+  den.aspects.desktop.game.heroic = {
+    cacheHome = {config, ...}: {
+      directories = [
+        "${config.xdg.config.directory}/heroic"
+        "${config.xdg.state.directory}/Heroic"
+        "${config.xdg.data.directory}/umu"
+      ];
+    };
+
+    hjem = {
+      pkgs,
+      osConfig,
+      ...
+    }: {
+      packages = [
+        pkgs.heroic
+      ];
+
+      xdg.config.files = lib.mergeAttrsList (
+        map
+        (w: {"heroic/tools/proton/${w.pname}".source = w.steamcompattool;})
+        osConfig.programs.steam.extraCompatPackages
+      );
+    };
+  };
+}

@@ -0,0 +1,38 @@
+{
+  den.aspects.desktop.game.hoyo = {
+    nixos = {
+      networking.hosts = {
+        "0.0.0.0" = [
+          "osuspider.yuanshen.com"
+          "overseauspider.yuanshen.com"
+          "uspider.yuanshen.com"
+
+          "log-upload-os.hoyoverse.com"
+          "log-upload-os.mihoyo.com"
+          "apm-log-upload-os.hoyoverse.com"
+          # "zzz-log-upload-os.hoyoverse.com"
+          "log-upload.mihoyo.com"
+          "ys-log-upload.mihoyo.com"
+          "ys-log-upload-os.hoyoverse.com"
+          "hkrpg-log-upload-os.hoyoverse.com"
+          "dump.gamesafe.qq.com"
+          "devlog-upload.mihoyo.com"
+
+          "globaldp-prod-cn01.bhsr.com"
+          # "globaldp-prod-cn01.juequling.com"
+
+          "sg-public-data-api.hoyoverse.com"
+          "public-data-api.mihoyo.com"
+
+          "prd-lender.cdp.internal.unity3d.com"
+          "thind-prd-knob.data.ie.unity3d.com"
+          "thind-gke-usc.prd.data.corp.unity3d.com"
+          "cdp.cloud.unity3d.com"
+          "remote-config-proxy-prd.uca.cloud.unity3d.com"
+
+          "pc.crashsight.wetest.net"
+        ];
+      };
+    };
+  };
+}

@@ -0,0 +1,17 @@
+{
+  den.aspects.desktop.game.ludusavi = {
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.config.directory}/ludusavi"
+      ];
+    };
+
+    hjem = {pkgs, ...}: {
+      # Use ludusavi to avoid add every Linux native game's
+      # data folder into persistence.
+      packages = [
+        pkgs.ludusavi
+      ];
+    };
+  };
+}

@@ -0,0 +1,54 @@
+{
+  den.aspects.desktop.game.mangohud = {
+    hjem = {
+      pkgs,
+      lib,
+      ...
+    }: let
+      renderOption = option:
+        rec {
+          int = toString option;
+          float = int;
+          path = int;
+          bool = "0"; # "on/off" opts are disabled with `=0`
+          string = option;
+          list = lib.concatStringsSep "," (lib.lists.forEach option toString);
+        }.${
+          builtins.typeOf option
+        };
+
+      renderLine = k: v: (
+        if lib.isBool v && v
+        then k
+        else "${k}=${renderOption v}"
+      );
+      renderSettings = attrs: lib.strings.concatStringsSep "\n" (lib.attrsets.mapAttrsToList renderLine attrs) + "\n";
+    in {
+      packages = [pkgs.mangohud];
+
+      xdg.config.files."MangoHud/MangoHud.conf" = {
+        generator = renderSettings;
+        value = {
+          fps = true;
+          frametime = true;
+
+          # Hardware stats
+          cpu_stats = true;
+          cpu_temp = true;
+          cpu_power = true;
+          cpu_mhz = true;
+          gpu_stats = true;
+          gpu_temp = true;
+          gpu_power = true;
+          gpu_core_clock = true;
+          gpu_mem_clock = true;
+          ram = true;
+          vram = true;
+
+          # Keybinds
+          toggle_hud = "Shift_R+F12";
+        };
+      };
+    };
+  };
+}

@@ -0,0 +1,17 @@
+{
+  den.aspects.desktop.game.minecraft = {
+    cacgeHome = {config, ...}: {
+      directories = [
+        "${config.xdg.data.directory}/PrismLauncher"
+      ];
+    };
+
+    hjem = {pkgs, ...}: {
+      packages = [
+        (pkgs.prismlauncher.override {
+          additionalPrograms = [pkgs.ffmpeg-headless];
+        })
+      ];
+    };
+  };
+}

@@ -0,0 +1,46 @@
+{den, ...}: {
+  den.aspects.desktop.game.includes = [den.aspects.desktop.game.misc];
+  den.aspects.desktop.game.misc = {
+    nixos = {pkgs, ...}: let
+      # Fix DualSense haptics until https://github.com/alsa-project/alsa-ucm-conf/issues/677 been resolved.
+      alsa-ucm-conf-dualsense-haptics = with pkgs;
+        alsa-ucm-conf.overrideAttrs {
+          # https://github.com/alsa-project/alsa-ucm-conf/issues/677#issuecomment-3759801501
+          patches = [
+            ./alsa-ucm-dualsense-haptics.patch
+          ];
+        };
+    in {
+      environment.sessionVariables.ALSA_CONFIG_UCM2 = "${alsa-ucm-conf-dualsense-haptics}/share/alsa/ucm2";
+
+      programs.gamemode.enable = true;
+
+      # load ntsync
+      boot.kernelModules = ["ntsync"];
+      # make ntsync device accessible
+      services.udev.packages = [
+        (pkgs.writeTextFile {
+          name = "ntsync-udev-rules";
+          text = ''KERNEL=="ntsync", MODE="0660", TAG+="uaccess"'';
+          destination = "/etc/udev/rules.d/70-ntsync.rules";
+        })
+      ];
+    };
+
+    provides.to-users = {
+      includes = [
+        {
+          cacheHome = {config, ...}: {
+            directories = [
+              config.xdg.user-dirs.directories.games
+            ];
+          };
+        }
+      ];
+
+      hjem = {config, ...}: {
+        xdg.user-dirs.directories.games = "${config.directory}/Games";
+      };
+    };
+  };
+}

@@ -0,0 +1,66 @@
+{
+  den.aspects.desktop.game.steam = {
+    cacheHome = {config, ...}: {
+      directories = [
+        "${config.xdg.config.directory}/millennium"
+        "${config.xdg.data.directory}/millennium"
+        "${config.xdg.data.directory}/Steam"
+        ".steam"
+      ];
+    };
+
+    nixos = {pkgs, ...}: let
+      millennium-src = pkgs.fetchFromGitHub {
+        owner = "SteamClientHomebrew";
+        repo = "Millennium";
+        rev = "v3.3.1";
+        hash = "sha256-nqNRtEkYgXawzpw/xCAgMSyaHKl5GFvzKm8WOoaUN24=";
+      };
+      millennium = pkgs.callPackage "${millennium-src}/packages/nix/millennium.nix" {inherit millennium-src;};
+      millennium-steam = pkgs.callPackage "${millennium-src}/packages/nix/steam.nix" {inherit millennium;};
+    in {
+      hardware = {
+        steam-hardware.enable = true;
+      };
+
+      programs.steam = {
+        enable = true;
+        dedicatedServer.openFirewall = true;
+
+        extraCompatPackages = [
+          pkgs.proton-ge-bin
+          pkgs.dwproton-bin
+          pkgs.nur.repos.vladexa.proton-cachyos-v3
+        ];
+
+        package = millennium-steam.override {
+          extraEnv = {
+            MANGOHUD = true;
+            OBS_VKCAPTURE = true;
+            PROTON_ENABLE_WAYLAND = true;
+            PROTON_ENABLE_HDR = true;
+            PROTON_USE_NTSYNC = true;
+            PROTON_USE_WOW64 = true;
+          };
+        };
+      };
+
+      # https://steamdeck-packages.steamos.cloud/archlinux-mirror/jupiter-main/os/x86_64/steamos-customizations-jupiter-20250117.1-1-any.pkg.tar.zst
+      boot.kernel.sysctl = {
+        # 20-shed.conf
+        "kernel.sched_cfs_bandwidth_slice_us" = 3000;
+        # 20-net-timeout.conf
+        # This is required due to some games being unable to reuse their TCP ports
+        # if they're killed and restarted quickly - the default timeout is too large.
+        "net.ipv4.tcp_fin_timeout" = 5;
+        # 30-splitlock.conf
+        # Prevents intentional slowdowns in case games experience split locks
+        # This is valid for kernels v6.0+
+        "kernel.split_lock_mitigate" = 0;
+        # 30-vm.conf
+        # USE MAX_INT - MAPCOUNT_ELF_CORE_MARGIN.
+        "vm.max_map_count" = 2147483642;
+      };
+    };
+  };
+}

@@ -0,0 +1,121 @@
+{
+  den.aspects.desktop.ime.fcitx5 = {
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.data.directory}/fcitx5/rime" # RIME data
+      ];
+    };
+
+    nixos = {
+      pkgs,
+      config,
+      ...
+    }: let
+      rime-frost = pkgs.stdenvNoCC.mkDerivation (finalAttrs: {
+        pname = "rime-ice";
+        version = "0-unstable-2026-08-16";
+
+        src = pkgs.fetchFromGitHub {
+          owner = "gaboolic";
+          repo = "rime-frost";
+          rev = "6b74e54da2737d9b9ba8c502ce697145f94504ba";
+          hash = "sha256-NKqjw7izkbNll9dM9qhjgW0IXUFz4o3l9uVOckyLx+w=";
+        };
+
+        installPhase = ''
+          runHook preInstall
+
+          rm -rf others README.md .git*
+
+          mv default.yaml rime_frost_suggestion.yaml
+
+          mkdir -p $out/share
+          cp -r . $out/share/rime-data
+
+          runHook postInstall
+        '';
+
+        meta = {
+          homepage = "https://github.com/gaboolic/rime-frost";
+          changelog = "https://github.com/gaboolic/rime-frost/blob/main/others/CHANGELOG.md";
+          license = pkgs.lib.licenses.gpl3Only;
+        };
+      });
+    in {
+      i18n.inputMethod = {
+        enable = true;
+        type = "fcitx5";
+
+        fcitx5 = {
+          addons = with pkgs; [
+            (fcitx5-rime.override {rimeDataPkgs = [rime-frost];})
+            fcitx5-gtk # gtk im module
+          ];
+          waylandFrontend = !config.services.xserver.enable;
+        };
+      };
+    };
+
+    provides.to-users = {
+      hjem = {
+        pkgs,
+        lib,
+        ...
+      }: let
+        iniFormat = pkgs.formats.ini {};
+        iniGlobalFormat = pkgs.formats.iniWithGlobalSection {};
+        yamlFormat = pkgs.formats.yaml {};
+
+        normalizeFcitx5Value = value:
+          if lib.isAttrs value
+          then lib.mapAttrs (_: normalizeFcitx5Value) value
+          else if builtins.isList value
+          then map normalizeFcitx5Value value
+          else if builtins.isBool value
+          then
+            if value
+            then "True"
+            else "False"
+          else value;
+      in {
+        xdg.config.files."fcitx5/profile" = {
+          generator = value: iniFormat.generate "fcitx5-profile" (normalizeFcitx5Value value);
+          value = {
+            GroupOrder."0" = "Default";
+            "Groups/0" = {
+              Name = "Default";
+              "Default Layout" = "us";
+              DefaultIM = "rime";
+            };
+            "Groups/0/Items/0" = {
+              Name = "keyboard-us";
+              Layout = "us";
+            };
+            "Groups/0/Items/1" = {
+              Name = "rime";
+              Layout = "us";
+            };
+          };
+        };
+        xdg.config.files."fcitx5/conf/rime.conf" = {
+          generator = value: iniGlobalFormat.generate "fcitx5-conf-rime.conf" (normalizeFcitx5Value value);
+          value = {
+            globalSection = {
+              PreeditMode = "Composing text";
+              InputState = "All";
+              PreeditCursorPositionAtBeginning = true;
+              SwitchInputMethodBehavior = "Commit commit preview";
+            };
+          };
+        };
+
+        xdg.data.files."fcitx5/rime/default.custom.yaml" = {
+          generator = yamlFormat.generate "fcitx5-rime-default.custom.conf";
+          value = {
+            patch.__include = "rime_frost_suggestion:/";
+          };
+        };
+      };
+    };
+  };
+}

@@ -0,0 +1,110 @@
+{
+  den.aspects.desktop.noctalia = {
+    persistHome = {config, ...}: {
+      directories = [
+        "${config.xdg.state.directory}/noctalia"
+      ];
+    };
+
+    hjem = {
+      user,
+      pkgs,
+      lib,
+      ...
+    }: let
+      noctalia-src = pkgs.fetchFromGitHub {
+        owner = "noctalia-dev";
+        repo = "noctalia";
+        tag = "v5.0.0-beta.8";
+        hash = "sha256-qy3Cheg/FQ9ZaBPTIgdq4IkmkNtC6XBpmtC8nT+wU/Y=";
+      };
+      noctalia = pkgs.callPackage "${noctalia-src}/nix/package.nix" {};
+    in {
+      packages = [noctalia];
+
+      xdg.config.files."noctalia/config.toml" = {
+        generator = value: let
+          rawConfig = (pkgs.formats.toml {}).generate "noctalia-config.toml" value;
+        in
+          pkgs.runCommand "noctalia-config-validated.toml" {} ''
+            ${lib.getExe noctalia} config validate ${rawConfig}
+            cp ${rawConfig} $out
+          '';
+        value = {
+          battery.warning_threshold = 20;
+          notification.layer = "overlay";
+          osd = {
+            background_opacity = 0.9;
+            position_vertical = "top_right";
+          };
+          desktop_widgets.enabled = false;
+          shell = {
+            avatar_path = lib.mkIf (user.identity.avatar != null) user.identity.avatar;
+            lang = "zh_CN.UTF-8";
+            panel = {
+              open_near_click_control_center = true;
+              transparency_mode = "glass";
+            };
+          };
+          bar = {
+            order = ["default"];
+            default = {
+              background_opacity = 0.9;
+              margin_edge = 8;
+              margin_ends = 8;
+              radius = 14;
+              start = ["launcher" "privacy" "media"];
+              center = ["workspaces"];
+              end = [
+                "tray"
+                "notifications"
+                "clipboard"
+                "network"
+                "bluetooth"
+                "volume"
+                "brightness"
+                "battery"
+                "clock"
+                "control-center"
+              ];
+            };
+          };
+          widget = {
+            battery = {
+              display_mode = "graphic";
+              show_label = false;
+            };
+            brightness.show_label = false;
+            clock = {
+              capsule = true;
+              capsule_opacity = 0.9;
+              capsule_padding = 10.0;
+              format = "{:%Y-%m-%d %H:%M}";
+            };
+            control-center = {
+              capsule = true;
+              capsule_opacity = 0.9;
+              custom_image = "${pkgs.nixos-icons}/share/icons/hicolor/64x64/apps/nix-snowflake.png";
+            };
+            launcher = {
+              capsule = true;
+              capsule_opacity = 0.9;
+            };
+            media = {
+              capsule = true;
+              capsule_opacity = 0.9;
+            };
+            network.show_label = false;
+            privacy = {
+              capsule = true;
+              capsule_opacity = 0.9;
+            };
+            tray = {drawer = true;};
+            volume.show_label = false;
+            workspaces.hide_when_empty = true;
+          };
+        };
+      };
+    };
+  };
+}

@@ -0,0 +1,50 @@
+{den, ...}: {
+  den.aspects.desktop.noctalia.includes = [
+    (
+      den.lib.policy.when
+      ({user, ...}: user.hasAspect den.aspects.desktop.wm.niri)
+      den.aspects.desktop.noctalia.integration.niri
+    )
+  ];
+
+  den.aspects.desktop.noctalia.integration = {
+    niri = {
+      hjem = {
+        xdg.config.files."noctalia/config.toml".value = {
+          backdrop.enabled = true;
+        };
+
+        xdg.config.files."niri/nix/pre.kdl".text = ''
+          spawn-at-startup "noctalia"
+          layer-rule {
+          	match namespace="^noctalia-backdrop"
+          	place-within-backdrop true
+          }
+          layer-rule {
+          	match namespace="^noctalia-(bar-[^\"]+|notification|dock|panel|attached-panel|osd)$"
+          	background-effect { xray false; }
+          }
+          window-rule {
+           	match app-id="dev.noctalia.Noctalia.Settings"
+           	open-floating true
+           	background-effect { xray false; }
+           	default-column-width { fixed 1080; }
+           	default-window-height { fixed 920; }
+          }
+        '';
+
+        xdg.config.files."niri/nix/keybinds.kdl".value = {
+          "Mod+Space" = ''spawn-sh  "noctalia msg panel-toggle launcher"'';
+          "Mod+X" = ''spawn-sh "noctalia msg panel-toggle control-center"'';
+          "Mod+V" = ''spawn-sh "noctalia msg panel-toggle clipboard"'';
+          "Mod+Alt+L" = ''spawn-sh "noctalia msg session lock"'';
+          "XF86AudioRaiseVolume" = ''spawn-sh "noctalia msg volume-up"'';
+          "XF86AudioLowerVolume" = ''spawn-sh "noctalia msg volume-down"'';
+          "XF86AudioMute" = ''spawn-sh "noctalia msg volume-mute"'';
+          "XF86MonBrightnessUp" = ''spawn-sh "noctalia msg brightness-up"'';
+          "XF86MonBrightnessDown" = ''spawn-sh "noctalia msg brightness-down"'';
+        };
+      };
+    };
+  };
+}

@@ -0,0 +1,11 @@
+include "nix/pre.kdl"
+
+include "inputs.kdl"
+include "keybinds.kdl"
+include "layout.kdl"
+include "misc.kdl"
+include "window-rules.kdl"
+include "workspaces.kdl"
+
+include "nix/post.kdl"
+

@@ -0,0 +1,8 @@
+input {
+  touchpad {
+    tap
+    natural-scroll
+    dwt
+    drag true
+  }
+}

@@ -0,0 +1,129 @@
+binds {
+  // === Common Binds ===
+  Mod+Shift+Slash         { show-hotkey-overlay; }
+  Mod+Escape repeat=false { toggle-overview; }
+
+  Mod+Shift+E     { quit; }
+  Ctrl+Alt+Delete { quit; }
+
+  Print       { screenshot; }
+  Mod+Shift+S { screenshot; }
+  Ctrl+Print  { screenshot-screen; }
+  Alt+Print   { screenshot-window; }
+
+  // === Window and Column Actions ===
+  Mod+Q repeat=false { close-window; }
+
+  Mod+H     { focus-column-left; }
+  Mod+J     { focus-window-down; }
+  Mod+K     { focus-window-up; }
+  Mod+L     { focus-column-right; }
+  Mod+Left  { focus-column-left; }
+  Mod+Down  { focus-window-down; }
+  Mod+Up    { focus-window-up; }
+  Mod+Right { focus-column-right; }
+  Mod+Home  { focus-column-first; }
+  Mod+End   { focus-column-last; }
+  Mod+WheelScrollRight      { focus-column-right; }
+  Mod+WheelScrollLeft       { focus-column-left; }
+  Mod+Shift+WheelScrollDown { focus-column-right; }
+  Mod+Shift+WheelScrollUp   { focus-column-left; }
+
+  Mod+Ctrl+H     { move-column-left; }
+  Mod+Ctrl+J     { move-window-down; }
+  Mod+Ctrl+K     { move-window-up; }
+  Mod+Ctrl+L     { move-column-right; }
+  Mod+Ctrl+Left  { move-column-left; }
+  Mod+Ctrl+Down  { move-window-down; }
+  Mod+Ctrl+Up    { move-window-up; }
+  Mod+Ctrl+Right { move-column-right; }
+  Mod+Ctrl+Home  { move-column-to-first; }
+  Mod+Ctrl+End   { move-column-to-last; }
+  Mod+Ctrl+WheelScrollRight      { move-column-right; }
+  Mod+Ctrl+WheelScrollLeft       { move-column-left; }
+  Mod+Ctrl+Shift+WheelScrollDown { move-column-right; }
+  Mod+Ctrl+Shift+WheelScrollUp   { move-column-left; }
+
+  Mod+Minus       { set-column-width "-10%"; }
+  Mod+Equal       { set-column-width "+10%"; }
+  Mod+Shift+Minus { set-window-height "-10%"; }
+  Mod+Shift+Equal { set-window-height "+10%"; }
+
+  Mod+R       { switch-preset-column-width; }
+  Mod+Shift+R { switch-preset-window-height; }
+  Mod+Ctrl+R  { reset-window-height; }
+
+  Mod+F            { maximize-column; }
+  Mod+Shift+F      { fullscreen-window; }
+  Mod+Ctrl+F       { maximize-window-to-edges; }
+  Mod+Ctrl+Shift+F { toggle-windowed-fullscreen; }
+
+  Mod+BracketLeft  { consume-or-expel-window-left; }
+  Mod+BracketRight { consume-or-expel-window-right; }
+  Mod+Comma        { consume-window-into-column; }
+  Mod+Period       { expel-window-from-column; }
+
+  Mod+Ctrl+W { toggle-window-floating; }
+  Mod+W      { switch-focus-between-floating-and-tiling; }
+
+  Mod+T { toggle-column-tabbed-display; }
+
+  // === Workspace Actions ===
+  Mod+Page_Down { focus-workspace-down; }
+  Mod+Page_Up   { focus-workspace-up; }
+  Mod+D { focus-workspace-down; } // Default is `U`, use Helix binding instead.
+  Mod+U { focus-workspace-up; }   // Default is `I`, use Helix binding instead.
+  Mod+WheelScrollDown cooldown-ms=150 { focus-workspace-down; }
+  Mod+WheelScrollUp   cooldown-ms=150 { focus-workspace-up; }
+
+  Mod+Ctrl+Page_Down { move-column-to-workspace-down; }
+  Mod+Ctrl+Page_Up   { move-column-to-workspace-up; }
+  Mod+Ctrl+D { move-column-to-workspace-down; }
+  Mod+Ctrl+U { move-column-to-workspace-up; }
+  Mod+Ctrl+WheelScrollDown cooldown-ms=150 { move-column-to-workspace-down; }
+  Mod+Ctrl+WheelScrollUp   cooldown-ms=150 { move-column-to-workspace-up; }
+
+  Mod+Shift+Page_Down { move-workspace-down; }
+  Mod+Shift+Page_Up   { move-workspace-up; }
+  Mod+Shift+D { move-workspace-down; }
+  Mod+Shift+U { move-workspace-up; }
+
+  Mod+1 { focus-workspace 1; }
+  Mod+2 { focus-workspace 2; }
+  Mod+3 { focus-workspace 3; }
+  Mod+4 { focus-workspace 4; }
+  Mod+5 { focus-workspace 5; }
+  Mod+6 { focus-workspace 6; }
+  Mod+7 { focus-workspace 7; }
+  Mod+8 { focus-workspace 8; }
+  Mod+9 { focus-workspace 9; }
+
+  Mod+Ctrl+1 { move-column-to-workspace 1; }
+  Mod+Ctrl+2 { move-column-to-workspace 2; }
+  Mod+Ctrl+3 { move-column-to-workspace 3; }
+  Mod+Ctrl+4 { move-column-to-workspace 4; }
+  Mod+Ctrl+5 { move-column-to-workspace 5; }
+  Mod+Ctrl+6 { move-column-to-workspace 6; }
+  Mod+Ctrl+7 { move-column-to-workspace 7; }
+  Mod+Ctrl+8 { move-column-to-workspace 8; }
+  Mod+Ctrl+9 { move-column-to-workspace 9; }
+
+  // === Monitor Actions ===
+  Mod+Shift+H     { focus-monitor-left; }
+  Mod+Shift+J     { focus-monitor-down; }
+  Mod+Shift+K     { focus-monitor-up; }
+  Mod+Shift+L     { focus-monitor-right; }
+  Mod+Shift+Left  { focus-monitor-left; }
+  Mod+Shift+Down  { focus-monitor-down; }
+  Mod+Shift+Up    { focus-monitor-up; }
+  Mod+Shift+Right { focus-monitor-right; }
+
+  Mod+Ctrl+Shift+H     { move-column-to-monitor-left; }
+  Mod+Ctrl+Shift+J     { move-column-to-monitor-down; }
+  Mod+Ctrl+Shift+K     { move-column-to-monitor-up; }
+  Mod+Ctrl+Shift+L     { move-column-to-monitor-right; }
+  Mod+Ctrl+Shift+Left  { move-column-to-monitor-left; }
+  Mod+Ctrl+Shift+Down  { move-column-to-monitor-down; }
+  Mod+Ctrl+Shift+Up    { move-column-to-monitor-up; }
+  Mod+Ctrl+Shift+Right { move-column-to-monitor-right; }
+}